Windows 7 อ่านภาษาญี่ปุ่นเป็น สี่เหลี่ยมครับ

[Zidane]

ใครทราบวิธีแก้บอกด้วยนะครับ
*อัพเดทแล้ว แต่ขึ้น error ตลอต วิน ผี ครับ
นั่งหาตามเน็ตก็แก้ไม่ได้เลย

http://upic.me/i/no/win7error.jpg

[hpz]

ขอแก้ตัวแทน windows 7 นะครับ จากรูปมันไม่เกี่ยวกัน windows นะครับ นั้นมันเป็นที่ web brower

[Zidane]

ไฟล์ภาษา ญี่ปุ่นในเครื่องเป็นหมดครับ
http://upic.me/i/4a/win7error02.jpg

[hpz]

อาห์ อันนี้ชัดเจน




ถ้าเป็นเช่นนั้นลองแก้ไขปัญหาดังกล่าวด้วยขั้นตอนดังต่อไปนี้ครับ
ขั้นตอนที่ 1
1. คลิ๊กปุ่ม Start>Control panel
2. คลิ๊กที่หมวด Clock, Language, and Region
3. ภายใต้หัวข้อ Region and Language ให้คลิ๊กที่แถบ Change location
4. แล้วคลิ๊กที่แถบ Administrative> แล้วกดปุ่ม Change system locale…
5. ถ้ายสุด ให้เปลี่ยน Current system locale เป็น Japanese (Japan) แล้วกด OK
หลังจากนั้นทำการ Restart เครื่องของคุณ

ขั้นตอนที่ 2
1. คลิ๊กปุ่ม Start>Control panel
2. คลิ๊กที่หมวด Clock, Language, and Region
3. ภายใต้หัวข้อ Region and Language ให้คลิ๊กที่แถบ Change location
4. แล้วคลิ๊กที่แถบ Administrative> แล้วกดปุ่ม Change system locale…
5. ถ้ายสุด ให้เปลี่ยน Current system locale เป็น Japanese (Japan) แล้วกด OK
6. หลังจากนั้นให้เปลี่ยนกลับเป็น English (United States) แล้วกด Ok ครับ
หลังจากนั้นทำการ Restart เครื่องของคุณ

หลังจากทำตามขั้นตอนที่ได้แนะนำไปแล้วแต่ปัญหายังไม่ถูกแก้ไขได้ ก็ให้ลองตามขั้นตอนที่ได้แนะนำไปนั้น สัก 2-3 ครั้งครับ


ได้ผลไม่ได้ผลอย่างไร ก็รบกวนแจ้งกลับมา ให้ทีมผมได้รับรู้ด้วยครับ ถ้าหากปัญหายังไม่ถูกแก้ไขได้ ทางทีมผมก็จะได้ค้นหาวิธีการอื่นๆ เพื่อแก้ไขปัญหาให้คุณต่อไปครับ


ขอบคุณครับ
จากทีมไมโครซอฟท์

[seedofriots]

http://www.yesjapan.com/install_japanese/ดูเอาครับ

[Zidane]

ขอบคุณทั้ง 2 คนครับ แต่ วิธีของคุณ hpz ผมลองแล้ว
กลายเป็นว่าเข้า windows ไม่ได้เลย ต้อง restore เข้าใหม่
วิธีของคุณ seedofriots ผมไม่มีตัว IME ให้เลือกครับ

[hpz]

อันเป็น 7 อะไรครับ Pro or Ultimate x86 or x64 sp1 หรือเปล่าครับ

[Zidane]

Ultimate x64 ครับ T-T

[hpz]

เห็นว่า windows update error งั้นคงต้องลองโหลดตัวภาษามาครับ
ตามนี้ http://www.mydigitallife.info/download-windows-7-mui-language-packs-official-32-bit-and-64-bit-direct-download-links/

ถ้าเป็น sp1 http://www.mydigitallife.info/windows-7-sp1-mui-language-packs-official-direct-download-links/

[Zidane]

Install ไม่เสร็จครับ นิ่งเลย ไม่มีอะไรเกิดขึ้น สงสัยอาจจะต้องลง winDows ไม่จริงๆ ตัวนี่เพิ่งลงไปได้ 2 อาทิตย์เอง
คุณ hpz ใช้ตัวไหนครับ พอจะมีลิงคืให้โหลดมั้ยครับ

[hpz]

ผมใช้ตัวจาก microsoft ครับ ส่วนการ Activate ใช้ทั้ง key หรือ ไม่ก็ ใช้ scrip oem ครับ ตอนนี้ก็เล่น scrip oem ครับ เป็น scrip จากเกาหลี ก็เอาแก้ไขอีกที

ถ้างั้นคงต้องลอง บังคับมันซะหน่อย save เป็น bat file นะครับ แล้วเอาไปใว้กับ file update หรือท่านจะลองอ่านๆๆดูแล้วก็แก้ไขให้มันถูกกับเครื่องของท่านก็ได้นะครับ


@echo off
title Installer for Windows 7 Updates
set loc=.
if exist "%temp%\cabtemp" echo Removing an existing installer cabtemp folder...&rd /s /q "%temp%\cabtemp"
set z=%windir%\system32\
if not exist "%z%\dism.exe" goto :systemerror
if not exist "%z%\expand.exe" goto :systemerror
set Count=0
set mrtd=0
set mrtl=0
set updates=0
set kb94x=0
set kb947821=0
set mincs=0
set mininstall=0
set kb1=0
set kb2=0
set kb3=0
set kb4=0
set kb958559=0
set kb958559c=0
set kb958559m=0
set kb2533552=0
set vpc=0
for /f "tokens=2 delims=[]" %%V in ('ver') Do (for /f "tokens=2" %%Y in ('echo %%V') Do (set winnum=%%Y))

reg query "hklm\software\microsoft\Windows NT\currentversion" /v buildlabex >"%temp%\OS.txt"
find /i "amd64" < "%temp%\os.txt" > nul
if %errorlevel% equ 0 set Arch=x64

if %PROCESSOR_ARCHITECTURE% equ x86 set Arch=x86
if %PROCESSOR_ARCHITECTURE% equ IA64 set Arch=IA64
del "%temp%\OS.txt"

if %winnum% lss 6.1.7600 goto :oldwin
if %winnum% equ 6.1.7600 set SP=RTM
for /L %%A in (1,1,4) do (if %winnum% equ 6.1.760%%A set SP=SP%%A)

set filename=*Windows6.1
rem retained for future modification once Windows 8 appears

if %Arch% equ x86 set System=Windows 7 x86
if %Arch% equ x64 set System=Windows 7/Server 2008 R2 x64
if %Arch% equ ia64 set System=Server 2008 R2 ia64

:menu
cd /d "%loc%"
call :title
set c=0
set d=0
if exist "%filename%*%arch%*.msu" (for /f %%a in ('dir "%filename%*%arch%*.msu" /b') do (call set /a c+=1))
if exist "%filename%*%arch%*.cab" (for /f %%a in ('dir "%filename%*%arch%*.cab" /b') do (call set /a d+=1))
if exist "%filename%*kb947821*%arch%*" (set /a c-=1&for /f %%G IN ('dir /b /on "%filename%*kb947821*%arch%*"') DO (set kb947821=%%G))
set /a e=%c%+%d% >nul
if %e% equ 0 goto :nofiles

if %c% neq 0 echo %c% .msu update(s) found for %system%
if %d% neq 0 echo %d% .cab update(s) found for %system%
if %c% neq 0 (if %d% neq 0 echo %e% updates total!)

call :line

echo.
if %count% equ 0 (echo C. Install updates. Installs LDR versions if available.) else (echo Option C hidden as you have just run it!)
if %mininstall% equ 1 echo (this option will now install all updates)
echo.
echo T. Tools menu
echo.
echo I. Information
echo.
echo X. Exit
echo.
echo.
Choice /c CTIX /N /M "Please enter your selection> "

if Errorlevel 4 Exit
if Errorlevel 3 Goto :Desc
if Errorlevel 2 Goto :toolsmenu
if Errorlevel 1 Goto :runcabmenu

goto :eof

:runcabmenu
if %mininstall% equ 1 goto :runcab
call :title
if exist %filename%*2533552-%arch%*.* (if not exist "%windir%\servicing\packages\*2533552*.mum" goto :servicingstack)
echo Would you like to just install updates that haven't already been
echo installed, or would you like to recheck all updates?
echo.
echo Please note that if you choose option 2 or 3, newer versions of the same
echo KB article will not be installed. If you wish to install these please
echo choose option 1.
call :line
echo.
echo 1. Process (install) all updates
echo.
echo 2. Only process updates that haven't already been installed
echo.
echo 3. This option is the same as option 2 except it skips these updates:
echo KB917607, KB943790, KB969168, KB974405, KB974674, KB982861, KB2506143
echo These do not leave KB package info like other updates, so will always
echo reprocess with option 2 even if they are installed.
echo.
echo 4. Return to the Main Menu
echo.
choice /c 1234 /N /M "Please enter your selection> "
if errorlevel 4 goto :menu
if errorlevel 3 set mincs=1&goto :runcabs
if errorlevel 2 goto :runcabs
if errorlevel 1 goto :runcab

:servicingstack
Echo Servicing stack installer, KB2533552 found but not installed on your
echo system. This should be installed before the other updates to ensure a
echo successful update process.
echo.
echo A reboot will be required for the update to take effect before you
echo continue installing.
echo.
echo.
echo Press any key to install update KB2533552...
pause >nul
if exist %filename%*kb2533552*%arch%*.msu (if not exist %filename%*kb2533552*%arch%*.cab (for /f %%G IN ('dir /b /on "%filename%*kb2533552*%arch%*.msu"') DO (set package=%%G&set c=1&md "%temp%\cabtemp"&call :startcab)))
if exist %filename%*kb2533552*%arch%*.cab (copy "%filename%*kb2533552*%arch%*.cab" "%temp%\cabtemp" >nul)
set count=0
set e=1
pushd "%temp%\cabtemp"
for /f %%G IN ('dir /b /on "%filename%*kb2533552*%arch%*.cab"') DO (call :startcab2 %%G)
set kb2533552=1
goto :3startcab

:runcabs
set mininstall=1
set count=0
md "%temp%\CabTemp" >nul


if exist "%filename%*kb958559*%arch%*.msu" (for /f %%G IN ('dir /b /on "%filename%*kb958559*%arch%*.msu"') DO (set kb958559m=%%G))
if exist "%filename%*kb958559*%arch%*.cab" (for /f %%G IN ('dir /b /on "%filename%*kb958559*%arch%*.cab"') DO (set kb958559c=%%G))

if exist *917607* (FOR /f %%G IN ('dir /b "*917607*"') DO (set kb917607=%%G))
if exist *943790* (FOR /f %%G IN ('dir /b "*943790*"') DO (set kb943790=%%G))
if exist *969168* (FOR /f %%G IN ('dir /b "*969168*"') DO (set kb969168=%%G))
if exist *971033* (FOR /f %%G IN ('dir /b "*971033*"') DO (set kb971033=%%G))
if exist *974405* (FOR /f %%G IN ('dir /b "*974405*"') DO (set kb974405=%%G))
if exist *974674* (FOR /f %%G IN ('dir /b "*974674*"') DO (set kb974674=%%G))
if exist *982861* (FOR /f %%G IN ('dir /b "*982861*"') DO (set kb982861=%%G))
if exist *2506143* (FOR /f %%G IN ('dir /b "*2506143*"') DO (set kb2506143=%%G))

if %c% neq 0 set c=0&set msu=1&(for /f "tokens=2 delims=-" %%V in ('dir %filename%*%arch%*.msu') Do (if not exist "%windir%\servicing\packages\*%%V*.mum" (if exist %filename%*%%V*%arch%*.msu (for /f %%G IN ('dir /b "%filename%*%%V*%arch%*.msu"') DO (call :runcabs2 %%G)))))

if %d% neq 0 set d=0&set msu=0&(for /f "tokens=2 delims=-" %%V in ('dir %filename%*%arch%*.cab') Do (if not exist "%windir%\servicing\packages\*%%V*.mum" (if exist %filename%*%%V*%arch%*.cab (for /f %%G IN ('dir /b "%filename%*%%V*%arch%*.cab"') DO (call :runcabs2 %%G)))))

set vpc=1

if exist %filename%*kb958559*%arch%*.msu (if not exist "%windir%\servicing\packages\*virtualpc*" (call :runcabs2 %kb958559m%))
if exist %filename%*kb958559*%arch%*.cab (if not exist "%windir%\servicing\packages\*virtualpc*" (call :runcabs2 %kb958559c%))
set /a e=%c%+%d% >nul

goto :runcab2a

:runcabs2
set package=%1
if %vpc% equ 0 (if %package% equ %kb958559m% goto :eof)
if %vpc% equ 0 (if %package% equ %kb958559c% goto :eof)

if %mincs% neq 1 goto :runcabs3

if "%package%" equ "%kb917607%" goto :eof
if "%package%" equ "%KB943790%" goto :eof
if "%package%" equ "%KB969168%" goto :eof
if "%package%" equ "%KB971033%" goto :eof
if "%package%" equ "%KB974405%" goto :eof
if "%package%" equ "%KB974674%" goto :eof
if "%package%" equ "%KB982861%" goto :eof
if "%package%" equ "%KB2506143%" goto :eof

goto :runcabs3

:runcabs3
if %msu% equ 0 (set /a d+=1&copy "%package%" "%temp%\cabtemp" >nul) else (set /a c+=1&call :startcab)
goto :eof

:runcab
set Count=0
md "%temp%\CabTemp" >nul
if %c% neq 0 for /f %%G IN ('dir /b /on "%filename%*%arch%*.msu"') DO (set package=%%G&call :startcab)
if %d% neq 0 copy %filename%*.cab "%temp%\cabtemp" >nul
if exist "Windows6.0-KB943790-%arch%.cab" (copy Windows6.0-KB943790-%arch%.cab "%temp%\cabtemp" >nul)

:runcab2a
pushd "%temp%\cabtemp"
if exist "Windows6.0-KB943790-%arch%.cab" ren "Windows6.0-KB943790-%arch%.cab" "Windows6.1-KB943790-%arch%.cab"

set count=0

if exist "%filename%*kb9*%arch%*.cab" for /f %%G IN ('dir /b /on "%filename%*kb9*%arch%*.cab"') DO (ren %%G 1%%G)
for /L %%A in (2,1,5) do (if exist "%filename%*kb%%A*%arch%*.cab" for /f %%G IN ('dir /b /on "%filename%*kb%%A*%arch%*.cab"') DO (ren %%G %%A%%G))
if exist "1%filename%*kb958559*%arch%*.cab" (for /f %%G IN ('dir /b /on "1%filename%*kb958559*%arch%*.cab"') DO (set kb958559=%%G))

if %e% leq 1 (if %kb958559% neq 0 set count=1&goto :listcreatedone)
if %e% equ 0 goto :finishedcab

for /f %%G IN ('dir /b /on "*.cab"') DO (call :startcab2 %%G)
goto :3startcab

:startcab
if "%kb947821%" equ "%package%" goto :eof
call :title
set /a count+=1
echo This process will be quite fast, however it will require
echo the use of some disk space.
echo.
echo.
echo Extracting cabinets (.cab) from .msu files
echo __________________________________________
echo.
echo %arch% file %count% of %c%: "%package%"
echo to folder "%temp%\CabTemp"
%z%expand -f:*%arch%*.cab "%package%" "%Temp%\CabTemp" >nul
goto :eof


:startcab2
set package=%1
if "%package%" equ "%kb958559%" goto :eof
Title Installer for Windows 7 Updates
call :title
set /a count+=1
echo This will require some disk space, please be patient!
echo.
echo.
echo Extracting files from update cabinets (.cab)
echo ____________________________________________
echo.
echo Processing %arch% cabinet %count% of %e%: "%package%"
md m%package%
%z%expand /f:* "%package%" "m%package%" >nul
goto :eof

:3startcab
call :title
echo.
echo Finding GDR and LDR packages...
echo _______________________________
echo.
echo This may take a few moments!
set listc=1
set list=1
set AC=125
for /f "tokens=8-9 delims=\ " %%a IN ('dir /b /on "update*.mum" /s /b') DO (set file=%%a\%%b&call :listcreate)
set /a listc-=1
goto :listcreatedone

:listcreate
echo.|set /p tmp=/packagepath:"%file%">> "list%list%.txt"
if %listc% equ %AC% (set /a AC+=125&set /a list+=1)
set /a listc+=1
goto :eof

:listcreatedone
setLocal EnableDelayedExpansion
echo Done.
echo.
call :line
echo.
echo Now installing!
echo.
set lc=1

:PP
set ldr=
if not exist list%lc%.txt (if exist %kb958559% (Title Installing Microsoft Virtual-PC&%z%dism.exe /Online /NoRestart /Add-Package %vpc%&goto :finishedcab) else goto :finishedcab)
if %lc% equ 1 (if %kb958559% neq 0 set vpc=/packagepath:"%kb958559%"&set ldr=!ldr! %vpc%)
for /F "delims=" %%i in ('type "list%lc%.txt"') do set ldr=!ldr! %%i
Title Update list %lc% of %list%, %listc% GDR and force LDR packages total
%z%dism.exe /Online /NoRestart /Add-Package %ldr%
set /a lc+=1
goto :PP

:finishedcab
popd
call :title
Title Installer for Windows 7 Updates
echo Please wait whilst temporary install files are removed...
rd /s /q "%temp%\CabTemp"
call :line
echo.
if %kb2533552% equ 1 echo Windows Servicing Stack update KB2533552 now installed.&echo Please restart computer now for it to take effect.&goto :fin
if %count% equ 0 (if %mininstall% equ 1 echo There were no new updates requiring installation.&if exist "%systemroot%\winsxs\pending.xml" (echo A previous operation requires you to restart, please do so ASAP!)&call :pak&goto :menu)
if %count% geq 1 echo Installing all updates completed.
if exist "%systemroot%\winsxs\pending.xml" (echo A restart is required, please do so ASAP!) else (echo A restart appears not to be needed!)
if %mininstall% equ 1 set count=0
call :pak
goto :menu

:checksur
if %kb94x% equ 1 goto :toolsmenu
call :title
if not exist "%KB947821%" goto :csloc
echo Currently running kb947821 - 'System Update Readiness Tool'.
echo.
echo This may take a very considerable time. A prompt to return to the
echo menu will appear once the tool has completed.
echo.
echo ***Please be patient!***
%kb947821% /quiet
echo.
echo Tool has been run. If the process was almost instaneous, please
echo check that you have the latest version and that the file is
echo not corrupt.
popd
set kb94x=1
call :pak
goto :toolsmenu

:csloc
call :title
echo Update KB947821 not found in the&if %kb94x% equ 0 (echo current location.) else (echo location that you entered.)
echo.
echo A. Select location of update KB947821 (%filename%-KB947821-X-%arch%.msu)
echo (X is the version of KB947821)
echo.
echo B. Return to the main menu
echo.
Choice /c AB /N /M "Please enter your selection> "
if errorlevel 2 set kb94x=0&popd&goto :menu
call :title
echo Please enter location of update %filename%-KB947821-X-%arch%.msu
echo 'X' is the version of KB947821. The latest should always be used.
echo It is also known as the 'System Update Readiness Tool'.
call :locinstr
echo Enter location:
set /p csloc=
pushd "%csloc%"
set /a kb94x=1
goto :checksur


:Desc
cls
echo -------------------
echo DESCRIPTION: Page 1
echo -------------------
echo.
echo Installing a large number of updates can take a considerable amount
echo of time, particularly when running each update separately in its .MSU
echo form (even if automated via a script). The purpose of this script
echo is to install the updates as fast as possible, and make use of the
echo LDR ('higher' updateness) codepath where possible.
echo.
echo This script achieves this by first extracting the .cab files from the
echo .msu files and then extracting the contents of the .cab files. This
echo isn't a wasteful process as no matter which way the updates are
echo installed its part of the update process, just this script does them
echo in bulk.
call :np

echo -------------------
echo DESCRIPTION: Page 2
echo -------------------
echo.
echo After this process has completed, the script finds the update files and
echo paths and builds update lists which are then passed to the Windows DISM
echo (Deployment Image Servicing Management) tool which installs the updates.
echo.
echo By building the lists, DISM only needs to be run once every 125 update
echo tasks, which is significantly quicker than running it individually on
echo each task.
echo.
echo The update filesnames on this current system must follow the naming
echo convention %filename%xxxxx-%arch%xx.x, where xxxxx is usually -KB
echo followed by the KB article number, xx is -V2, -V3 etc, which is
echo only present for a later release of the same KB article update, and x
echo is either the extension .cab or .msu
call :np

echo -------------------
echo DESCRIPTION: Page 3
echo -------------------
echo.

echo This script works on all versions of Windows 7,
echo and is service pack compatible. If the updates belong to a different
echo service branch than your system, for instance trying to install a RTM
echo update on Service Pack 1, it will be processed, but not installed.
echo.
echo The script will only install the update if its applicable to the current
echo Windows installation. This is just an automated process of running each
echo update.
echo.
echo This script can be used on an installation with any state of updatedness,
echo all that is required is that you have new updates for the relevant
echo architecture (x86/x64) and service branch (RTM/SP1 etc).

call :np

echo -------------------
echo DESCRIPTION: Page 4
echo -------------------
echo.
echo If you try at some stage to run this script on an older version of Windows
echo than 'Windows 7, the script will inform you that the
echo Windows version is too old and is unsupported by this script.
echo.
echo This script allows you to only install updates that haven't been installed
echo by cross referencing the update name with the packages name information stored
echo in the servicing folder. This is option 2 in the 'Install Updates' submenu.
echo.
echo Using this method, if an update doesn't store this update name (KBxxxxxxx)
echo information in the service packaging store the update will still be processed.
echo KB917607, KB943790, KB969168, KB974405, KB974674, and KB982861 are examples of
echo these. Since these are known, they can be skipped if you so with by choosing
echo option 3 on the 'Install Updates' submenu.
call :Np

echo -------------------
echo DESCRIPTION: Page 5
echo -------------------
echo.
echo Please note that updates that aren't applicable won't be skipped using this
echo method. Regardless of this, the option is there to expediate the installation
echo of new updates on an already mostly updated system. If there are a large
echo number of updates that have the correct name for your system but do not apply,
echo they may belong to the wrong service branch or you could have some other issue
echo with your system... please check that everything is correct!
echo.
echo If the Windows version is unknown, or is newer than Windows 7 Service Pack 3
echo (if and when it comes out), the script will inform you of the case. The
echo script may still be run, however there is no certainty that it will work
echo until an updated version of this script is available.
call :Np

echo -------------------
echo DESCRIPTION: Page 6
echo -------------------
echo.
echo This script also allows you to properly run update KB947821. This update
echo is actually a specific integrity check known as the 'System Update Readiness
echo Tool'. This update must be run in its original .msu form, option 1 in the
echo 'Tools menu' submeny allows you to do this.
echo.
echo Please note that KB947821 may take a very considerable time to complete!
echo.
echo Update KB890830 can also be run from the 'Tools menu' submenu by choosing
echo option 2. This is also a tool, known as the 'Microsoft Windows Malicious
echo Software Removal Tool'.
call :pak
goto :menu

:oldwin
echo.
echo The version of Windows you are running this install script on is too old.
echo Installer cannot continue. Please only run on Windows 7 or later.
goto :fin

:systemerror
call :title
echo Dism.exe or expand.exe could not be found in the usual location:
echo %windir%\system32.
echo Absense of these system files suggests a system or configuration error.
echo These are needed to install .msu and .cab files.
echo.
echo Please investigate why these files are missing before running this
echo script again.
goto :fin

:nofiles
call :line
echo.
echo There are no updates for the detected version of Windows in the
if %updates% equ 0 (echo current folder) else (echo location you entered.)
echo.
echo Please run this script from the same location as the update files,
echo or enter the location of the update files by selecting option 'A'
echo in the menu below.
echo.
echo The update files must begin with %filename%, they must be for
echo %arch%, denoted by -%arch% in the filename, and have the .msu
echo or .cab extension
echo.
echo A. Select location of updates
echo.
echo B. Information
echo.
echo C. Exit
echo.
Choice /c ABC /N /M "Please enter your selection> "
if errorlevel 3 goto :eof
if errorlevel 2 goto :desc

call :title
echo Please enter the location where the updates reside.
call :locinstr
echo Please enter location of updates then press enter:
set /P loc=
set updates=1
goto :menu

:locinstr
echo.
echo For ease of navigation you can locate the folder in Windows Explorer.
echo To do this, click on the space at the end of the address bar which will
echo highlight the current folder location. Copy the address to the clipboard
echo by pressing (ctrl-c) or click the right mouse button and selecting copy.
echo.
echo Paste the copied location into the script by clicking with the right mouse
echo button on this window and selecting paste.
call :line
echo.
goto :eof

:Mrt
if %mrtd% equ 1 goto :toolsmenu
call :title
if exist *KB890830*%arch%* goto :Mrt2
if %mrtl% equ 0 (echo Malicious Software Removal tool (MRT) KB890830 not found in current location) else (echo Update Windows MRT KB890830 does not exist in the location you just entered!)
call :line
echo.
echo.
echo Do you wish to enter location of KB890830 or return to the main menu?
echo.
echo A. Enter the location of KB890830
echo.
echo B. Return to the tools menu
echo.
echo.
Choice /c AB /N /M "Please enter your selection> "
if Errorlevel 2 goto :toolsmenu

call :title
echo Please enter the location of update KB890830
call :locinstr
echo Enter location containing KB890830:
set /P mrtl=
pushd "%mrtl%"
goto :mrt

:mrt2
echo Running the Microsoft Windows Malicious Software Removal Tool.
echo This may take a couple of minutes. A prompt to return to the
echo menu will appear once the tool has completed.
echo.
echo ***Please be patient!***
for /f %%G IN ('dir /b /on "*KB890830*%arch%*"') DO (%%G /q)
set mrtd=1
popd
echo.
echo Completed.
call :pak
goto :toolsmenu

:pak
echo.
echo.
echo Press any key to return to the menu...
Pause >nul
goto :eof

:title
cls
echo ----------------------------------------------
echo Installer for Windows 7 Updates
echo ----------------------------------------------
echo %System% %SP%
echo.
goto :eof

:line
echo ____________________________________________________________________________
goto :eof

:fin
echo.
echo.
echo Press any key to exit...
pause >nul
exit

:np
echo.
echo.
echo Press any key for the next page...
Pause >nul
cls
goto :eof

:toolsmenu
call :title
if %kb94x% equ 0 (echo 1. Run KB947821. As this is actually a tool, it needs to be run in&echo straight .msu form. This tool takes considerable time to run!) else (echo Option 1 hidden as you have just run it!)
echo.
if %mrtd% equ 0 (echo 2. Run KB890830, the 'Microsoft Windows Malicious Software Removal Tool') else (echo Option 2 hidden as you have just run it!)
echo.
rem echo 3. Integrate updates into an offline image
rem echo.
rem echo I. Information for these options
rem echo.
echo M. Main Menu
echo.
echo.
Choice /c 124M /N /M "Please enter your selection> "

if Errorlevel 4 goto :menu
rem if Errorlevel 5 goto :Desc2
rem if Errorlevel 3 goto :Integrate
if Errorlevel 2 goto :mrt
if Errorlevel 1 goto :checksur

echo 3. Return to tools menu
echo.
echo.
Choice /c 123 /N /M "Please enter your selection> "
if errorlevel 3 goto :toolsmenu

[Zidane]

file update อยู่ตรงไหนเหรอครับ -_-"

[hpz]

ก็ตัว ภาษา หรือ file kb ต่างๆที่ท่านโหลดมาครับ
อันนี้ผมหาไม่เจอละว่าผมโพสใว้ที่ไหน ถ้าว่างท่านจะโหลดก็ได้นะครับ pass น่าจะเป็น mona อันนี้ถ้าจำไม่ผิดมันจะ activate auto ถ้า bios เป็น 2.1 พวกที่ 2.0 จะเป็น loader ของ acrer เพิ่ม menu คลิกขวา ก็เครื่องมืออำนวยความสะดวกครับ เช่น device registry msconfig policy grant admin take ownership อะไรพวกนี้ล่ะครับ

x64 http://www.mediafire.com/myfiles.php#3qn9cg3so54hx
x86 http://www.mediafire.com/myfiles.php#4kzju2irjwafg

ตรวจสอบ link ก่อนโหลดนะครับ เพราะทำใว้ตั้งแต่ ออกมาใหม่ๆแล้ว HDD ยังไม่ว่าง ว่าจะออก ตัว BuildLabEx 7601.21831.amd64fre.win7sp1_ldr.111003-1503 ยังไม่มีเวลา

[Zidane]

เดี๋ยวลองดูครับ ขอบคุณมากๆครับ

**โหลดไม่ขึ้นเลยครับท่าน สงสัยไฟล์ไปซะแล้วครับ ขอบคุณมากครับ แต่ผมเริ่มๆปลงแล้วครับ:dash